map BLOCK LIST
map EXPR, LIST

Описание

Функция map вычисляет BLOCK или EXPR для каждого элемента списка LIST, и возвращает список, который содержит преобразованные элементы LIST.

#!/usr/bin/perl -w

use strict;

my @list = qw(нет ни лета ни зимы ни весны);

my @names = map {split ''} @list;

foreach (@list) {print $_." "}; print "\n";

foreach (@names) {print $_." "}; print "\n";

Вывод:

%perl map.pl
нет ни лета ни зимы ни весны
н е т н и л е т а н и з и м ы н и в е с н ы

По приниципу работы map напоминает foreach. В случае сложных вычислений, использование foreach может оказаться более предпочтительным, т.к. оно более наглядно и доступно для понимания.

От grep функция map отличается тем, что map возвращает список, который является результатом вычислений в рамках EXPR или BLOCK. А grep возвращает список элементов LIST, которые соответствуют заданному условию поиска в EXPR или BLOCK.

Т.е. по сути, grep используется в основном для поиска в заданном списке, а map - для преобразований.

Примеры использования map

Хэш на выходе

my @list = qw(нет ни лета ни зимы ни весны);

my %names = map {$_ => 1} @list;

foreach (keys %names) {print $_." = ". $names{$_}."\n"};

Вывод:

%perl map.pl
весны = 1
лета = 1
зимы = 1
ни = 1
нет = 1

Преобразование ссылок

#!/usr/bin/perl -w

use strict;

my @list = qw(<href="http://aninatalie.ru">MainPage</a>);

map { s/\&/&/g;
          s//>/g;
          s/\"/"/g;
          s/\015//g;} @list;


foreach (@list) {print $_.""};

Вывод:

%perl map.pl
<href="http://aninatalie.ru">MainPage</a>

grep - это встроенная в Perl функция, которая ищет в списке элементы, удовлетворяющие заданному условию. Используется для извлечения и преобразования данных.

Отличается от стандартной unix-программы grep тем, что стандартный grep выполняет поиск строк в одном или нескольких файлах, соответствующие заданному регулярному выражению.

Синтаксис

grep EXPR, LIST
grep BLOCK LIST

Описание

Функция вычисляет EXPR или BLOCK для каждого элемента LIST.

В списковом контексте возвращает элементы, для которых выражение EXPR или BLOCK является истинным. В скалярном контексте возвращает число - сколько элементов LIST соответствует заданному условию.

#!/usr/bin/perl -w

use strict;

my @list = qw(письма и телеграммы сгорели очень быстро и дотла
                были их килограммы теперь осталась только лишь зола);

my @result = grep /и/i, @list;
my $result_num = grep /и/i, @list;

foreach (@result) {print $_." "};

print "\n".$result_num."\n";

Вывод:

%perl grep.pl
письма и сгорели и были их килограммы лишь
8
%

Во время работы функция grep поочередно присваивает переменной $_ значения элементов из списка, и проверяет это значение на соответствие заданному условию. Одновременно с отбором элементов, можно вносить в них изменения.

Главное при этом помнить, что EXPR или BLOCK могут выполнять модификацию исходного списка.

my @list = qw(письма и телеграммы сгорели очень быстро и дотла
                были их килограммы теперь осталась только лишь зола);


my @result = grep s/и/i/, @list;

foreach (@list) {print $_." "};

Вывод:

%perl grep.pl
пiсьма i телеграммы сгорелi очень быстро i дотла былi iх кiлограммы теперь осталась только лiшь зола

Примеры

Поиск в сложной структуре данных

Есть список кандидатов на вакансию. Каждый кандидат обладает определенными навыками. Надо найти имена тех кандидатов, которые обладают списком заданных навыков (например: perl и mysql).

#!/usr/bin/perl -w

use strict;

my %persons = (
        'Мария' => [qw(html css mysql php perl xml apache)],
        'Сергей' => [qw(perl ruby apache nginx xml)],
        'Василий' => [qw(php html mysql)],
        'Захарий' => [qw(mysql oracle perl)],
);

my @names = grep {
                grep /mysql/, @{$persons{$_}} if grep /perl/, @{$persons{$_}};
        } keys %persons;


foreach (@names) {print $_." "};

Вывод:

Захарий Мария

Поиск в сложной структуре данных - 2

Требуется вывести имена сотрудников, специализирующихся на работе с oracle.

my @dbs = (
        {
                'name' => 'Natalie Ani',
                'specialization' => 'perl',
                'phone' => '4633',
        },
        {
                'name' => 'Mary Smirnova',
                'specialization' => 'ruby',
                'phone' => '4323',
        },
        {
                'name' => 'Alex Kravchik',
                'specialization' => 'oracle',
                'phone' => '4566',
        },
        {
                'name' => 'Alex Orlikov',
                'specialization' => 'oracle',
                'phone' => '4567',
        },
);

my @res = grep {
        $dbs[$_]->{'specialization'} eq 'oracle'
} 0..$#dbs;

foreach (@res) {print $dbs[$_]->{'name'}." "};

Вывод:

%perl grep.pl
Alex Kravchik Alex Orlikov

Поиск одновременно в нескольких массивах

my @names = grep /^А/, (@women_names, @men_names);

Поиск элементов по численному значению

my @num = qw(12 13 500 76 27 262 1 5 150 89 8);

my @res = grep {$_ < 100} @num;

Полезные ссылки

• Методы
  • tt_process
  • tt_config
    • TEMPLATE_OPTIONS
    • TEMPLATE_NAME_GENERATOR
  • tt_obj
  • tt_params
  • tt_clear_params
  • tt_pre_process
  • tt_post_process
  • tt_template_name
  • tt_include_path
• Полезные ссылки

CGI::Application поддерживает работу с шаблонами Template Toolkit с помощью CGI::Application::Plugin::TT .

Методы

tt_process

tt_process() - это "обертка" вокруг стандартного метода process() от Template Toolkit. Использование tt_process() похоже на использование process(). Методу tt_process можно передать до двух параметров. Первый - это имя вызываемого шаблона, второй - ссылка на хэш с передаваемыми в шаблон данными. Оба параметра являются не обязательными.

Если не указано имя шаблона, имя будет сгенерировано автоматически, с помощью функции $self->tt_template_name .

...
my $tt_params = {};
$tt_params->{'block'} = 'show_result';

return $self->tt_process('template.tt', $tt_params);
...

tt_process() возвращает скалярную ссылку на готовый к выводу пользователю код шаблона.

Пример:

...
my $scalar_link = $self->tt_process('template.tt', $tt_params);
print ${$scalar_link};
...

Вывод:

< html >

< head >
< meta http-equiv="Content-Type" content=" text/html; charset=windows-1251" / >

< title>Нумерология...< /title >

< style type="text/css" >
body {font-family: Verdana, Arial Cyr, Arial, Helvetica; font-weight: normal; font-size: 9pt;}




< body bgcolor="#ffffff" >
< center >
...

Фактически, полученный код не обязательно отправлять на вывод пользователю. Можно сохранить данные в файл, или разместить и отправить в электронном письме.

tt_config

Метод tt_config() позволяет задать некоторые параметры работы плагина CGI::Application::Plugin::TT и Template Toolkit. Рекомендуется вызывать метод tt_config() до того, как будут выполнены первые обращения к методам tt_process() и tt_obj(). Если хотите получить ошибку - сделайте наоборот.

TEMPLATE_OPTIONS

TEMPLATE_OPTIONS позволяет определить параметры для объекта Template. В списке можно указывать все классические конфигурационные опции Template Toolkit.

package App2;
...
sub setup {
	my $self = shift;
	$self->start_mode('on_start');	

	$self->tt_config(
		TEMPLATE_OPTIONS => {
			INCLUDE_PATH 	=> '/home/aninatalie.ru/templates',
		},
	);

	$self->run_modes(
		on_start	=> \&on_start,
		AUTOLOAD	=> sub { return 'Запрошенной страницы не существует' }
	);

}
...

TEMPLATE_NAME_GENERATOR

TEMPLATE_NAME_GENERATOR позволяет указать ссылку на функцию, которая будет генерировать имя файла шаблона. Данная функция будет выполняться, если метод tt_process() будет вызван без указания имени шаблона.

Если специальная функция не назначена, а tt_process() все-таки вызван без параметров - по-умолчанию будет сгенерировано имя шаблона на основе имен текущего модуля и метода.

package App2;
...
sub setup {
	my $self = shift;

	$self->mode_param('step');
	$self->start_mode('on_start');	

	$self->tt_config(
		TEMPLATE_NAME_GENERATOR => \&my_own_generator,
	);

	$self->run_modes(
		on_start	=> \&on_start,
		AUTOLOAD	=> sub { return 'Запрошенной страницы не существует' }
	);
}

sub my_own_generator {
	my $self = shift;	
	return 'error.tt',
}

sub on_start {
	my $self = shift;

	return $self->tt_process();
}

tt_obj

Метод tt_obj() возвращает ссылку на основной объект Template Toolkit. Используется, в основном, в процессе отладки приложения.

tt_params

Метод tt_params() определяет список параметров, которые будут передаваться в каждый вызываемый шаблон.

Как правило, при вызове метода tt_process(), ему передается ссылка на хэш с параметрами. Параметры, определенные с помощью tt_params() будут добавляться в этот хэш.

sub setup {
	my $self = shift;

	$self->mode_param('step');
	$self->start_mode('on_start');

	$self->tt_params(block => 'secret_page');

	$self->run_modes(
		on_start	=> \&on_start,
		AUTOLOAD	=> sub { return 'Запрошенной страницы не существует' }
	);
}
sub on_start {
	my $self = shift;
	my $q = $self->query();
	my $tt_params = {}; # к значениям данного хэша будут добавлены значения, заданные в tt_params()
	...
	return $self->tt_process('template2.tt', $tt_params);
}

Если один и тот же параметр определен дважды - преимуществом будет пользоваться параметр, который входит в хэш, передаваемый непосредственно tt_process().

Пример:

sub setup {
	my $self = shift;
	...
	$self->tt_params(block => 'show_result');
}

sub start {
	my $self = shift;
	my $tt_params = {
		block => 'show_form',
	};

	return $self->tt_process('template.tt', $tt_params);
}

В результате выполнения данного блока кода, в шаблоне будет использоваться параметр block со значением: "show_form".

tt_clear_params

Метод tt_clear_params() удалит все сохранившиеся до текущего времени параметры, установленные методом tt_params().

$self->tt_clear_params;

tt_pre_process

Метод tt_pre_process() действует аналогично методу cgiapp_prerun(). tt_pre_process() вызывается и отрабатывается непосредственно перед началом обработки шаблона.

Выполнение tt_pre_process() будет запущено автоматически, а на вход будут переданы те же параметры, которые передаются методу tt_process(). При желании, можно внести последние изменения в список передаваемых шаблону параметров.

sub tt_pre_process {
	my ($self, $file, $vars) = @_;
	$vars->{block}='show_result';
	print STDERR "start template process: $file \n";
	return;
}

tt_post_process

Метод tt_post_process() аналогичен методу cgiapp_postrun(). Вызывается автоматически после завершения обработки шаблона, но до отправления результата клиенту. На вход принимает скалярную ссылку на обработанный шаблон - готовый к выводу html-код.

sub tt_post_process {
	my ($self, $htmlref) = @_;

	print $htmlref;

	return;
}

tt_template_name

Метод генерирует название шаблона на основе имени вызывающих его класса и метода.

Например:

package App;

use base 'CGI::Application';
use CGI::Application::Plugin::TT;
 
sub setup {
	my $self = shift;

	$self->run_modes(
		on_start => 'start',
		...
	);
 
}

...
sub start {
	my $self = shift;

	my $template_name = $self->tt_template_name();
	return $self->tt_process($template_name);

}

Результат: Для вывода будет запрошен шаблон App/start.tmpl .

tt_template_name() позволяет формировать и использовать определенную иерархию шаблонов, зависимую от структуры самого приложения.

Можно заставить tt_template_name() сгенерировать название шаблона на основе не вызывающего метода, а вышестоящего по уровню. На сколько уровней выше - задается с помощью числа в качестве параметра.

Пример:

my $template_name = $self->tt_template_name(1);

Результат в файле error.log:

[Wed Jun  9 15:56:55 2010] [error] Error executing run mode 'on_start': file error - App/(eval)
.tmpl: not found at /home/aninatalie/aninatalie.ru/cgi-bin/app.cgi line 8\n

tt_template_name() вызывается автоматически, если при вызове метода tt_process() не было указано имя шаблона.

tt_include_path

Метод tt_include_path() позволяет указать путь к месторасположению шаблонов. Причем, на этапе, когда объект TT уже существует. Обычно для указания пути используют INCLUDE_PATH.

Вызов tt_include_path() внесет изменения в INCLUDE_PATH, что можно использовать во всех последующих вызовах объекта TT.

my $dir = '/home/aninatalie/aninatalie.ru/templates';
$self->tt_include_path( [$dir] );

Полезные ссылки

Дескриптор - handle - это уникальный номер, который используется для идентификации объектов. Обычно дескриптор используется при работе с API, при этом смысл значения дескриптора скрыт за этим API.

Смысл существования дескрипторов в том, чтобы как-то различать единообразные объекты между собой. Например, при открытии нескольких файлов для чтения, или при установлении нескольких соединений с базами данных.

CGI::Application::Plugin::DBH - используется для простого доступа к дескриптору DBI - dbh. Особенность работы с CGI::Application::Plugin::DBH состоит в том, что соединение с заранее определенной БД не устанавливается до тех пор, пока к этой БД не будет сделан хотя бы один запрос. Если приложение отработает без обращений к БД с запросами (например, на ранней стадии будет обнаружена ошибка и выполнение приложения будет прервано) - соединение не будет установлено. Экономия времени выполнения и ресурсов сервера очевидна.

Методы

dbh

	my @row_ary = $self->dbh->selectrow_array("SELECT * FROM table_name LIMIT 1");

Метод возвращает дескриптор базы данных DBI. Дескриптор создается при первом вызове данного метода, и просто возвращается при последующих обращениях к методу.

Если требуется использовать сразу несколько разных баз данных и, соответственно, дескрипторов, можно назначать для дескрипторов разные имена, и в дальнейшем обращаться к дескриптору по имени.

use CGI::Application::Plugin::DBH (qw/dbh_config dbh/);
...

sub cgiapp_init  {
	my $self = shift;

	$self->dbh_config('first_db_handle', 
		['DBI:mysql:database=bd1;host=localhost', 'user1', 'super_parol']);
	$self->dbh_config('second_db_handle',
		["DBI:mysql:database=bd2;host=localhost", 'user2', 'prosto_parol']);
}
...

sub on_start {
	my $self = shift;

	my $tt_params = {
		block => 'show_form',
	};

	my @row_ary = $self->dbh('first_db_handle')->selectrow_array("SELECT * FROM any_table LIMIT 1");
	$tt_params->{'info'} = \@row_ary;


	my $dbh2 = $self->dbh('second_db_handle');
	my @row_ary2 = $dbh2->selectrow_array("SELECT * FROM some_table LIMIT 1");
	$tt_params->{'info2'} = \@row_ary2;

	return $self->tt_process('template2.tt', $tt_params);
}

	my ($login) = $self->dbh->selectrow_array(
		"SELECT login FROM auth WHERE contract_id=$contract_id LIMIT 1");

	my $rows = $self->dbh->do("INSERT INTO auth (login, pass) VALUES (?, ?)", 
		undef, ($login, $pass));

	my $sql = "UPDATE auth SET contract_id=$contract_id WHERE login=$login";
	my $sth = $self->dbh->prepare($sql);
	$sth->execute;

dbh_config

sub cgiapp_init  {
	my $self = shift;

	$self->dbh_config("DBI:mysql:database=main_bd;host=localhost", 
		'main_user', 'main_user_password');
}

Метод dbh_config используется для установки параметров подключения к БД. Рекомендуется использовать метод внутри cgiapp_init. Главное, чтобы этот метод был выполнен задолго до того, как произойдет первый вызов dbh() , иначе все закончится очень печально - "500. Ошибочка вышла".

dbh_default_name

Метод dbh_default_name() указывает название дескриптора, который будет возвращаться "по-умолчанию", если имя дескриптора при вызове метода dbh() не указано. Используется при работе с двумя и более дескрипторами в одном приложении - очень удобно.

Если задать метод без параметров - вернет имя дескриптора, который назначен для вызова "по-умолчанию".

use CGI::Application::Plugin::DBH (qw/dbh_config dbh dbh_default_name/);

sub setup {
	my $self = shift;

	$self->dbh_default_name('first_db_handle');
	$self->dbh_config('first_db_handle', 
		['DBI:mysql:database=bd1;host=localhost', 'user1', 'super_parol']);
	$self->dbh_config('second_db_handle',
		["DBI:mysql:database=bd2;host=localhost", 'user2', 'prosto_parol']);

	$self->mode_param('step');
...
}
...

sub on_start {
	my $self = shift;

	my @row_ary = $self->dbh->selectrow_array("SELECT * FROM any_table LIMIT 1");

	my $dbh2 = $self->dbh('second_db_handle');
	my @row_ary2 = $dbh2->selectrow_array("SELECT * FROM some_table LIMIT 1");
...
}

Полезные ссылки

http://search.cpan.org/perldoc?DBI
http://search.cpan.org/~markstos/CGI-Application-4.31/lib/CGI/Application.pm
http://search.cpan.org/~markstos/CGI-Application-Plugin-DBH-4.00/lib/CGI/Application/Plugin/DBH.pm

Установка cookies

sub on_set_cookies {
	my $self = shift;
	my $query = $self->query();

	my $auth_cookie = $query->cookie( # подготавливаем cookie
			-name=>'alisa',
			-value=>'pass',
			-expires=>'+1h',
			-path=>'/cgi',
			-domain=>'.aninatalie.ru',
	);

	$self->header_props(-cookie=>[$auth_cookie]); # устанавливаем у клиента

	return $self->tt_process('template2.tt');
}

Получение информации из cookies

sub on_set_cookies {
	my $self = shift;
	my $query = $self->query();

	my $auth_cookie = $query->cookie('alisa');
		# Значение переменной $auth_cookie будет равно 'pass'. 
		# Т.е. мы получим только значение -value .

	...
	return $self->tt_process('template2.tt');
}

Обновление данных cookies

Удаление cookies

sub on_set_cookies {
	my $self = shift;
	my $query = $self->query();

	my $auth_cookie = $query->cookie(
			-name=>'alisa',
			-value=>'pass',
			-expires=>'-1h',
			-path=>'/cgi',
			-domain=>'.aninatalie.ru',
	);

	$self->header_props(-cookie=>[$auth_cookie]);

	return $self->tt_process('template2.tt');
}

Памятка

Что такое cookies

Cookie является решением одной из наследственных проблем HTTP протокола (HyperText Transfer Protocol). Проблема заключается в непостоянстве соединения между клиентом и сервером.

Используя cookie, можно эмулировать сессию по HTTP протоколу. Коротко принцип эмуляции сессии таков: на первом запросе выдается соотвествующее значение cookie, а при каждом последующем запросе это значение читается из переменной окружения HTTP_COOKIE и соответствующим образом обрабатывается.

Cookie - это небольшая порция текстовой информации, которую сервер передает браузеру. Браузер будет хранить эту информацию и передавать ее серверу с каждым запросом как часть HTTP заголовка.

Некоторые cookie могут храниться только в течение одной сессии, они удаляются после закрытия браузера. Другие, установленные на определенный период времени, записываются в файл(ы).

Формат и синтаксис cookie

Set-Cookie: name=VALUE; expires=DATE; path=PATH; domain=DOMAIN_NAME; secure

Set-Cookie: name=VALUE;

• name=VALUE - строка символов, исключая перевод строки, запятые и пробелы. NAME-имя cookie, VALUE - значение. Не допускается использование двоеточия, запятой и пробела.
• expires=DATE - время хранения cookie, т.е. вместо DATE должна стоять дата в формате "expires=Monday, DD-Mon-YYYY HH:MM:SS GMT", после которой истекает время хранения cookie. Если этот атрибут не указан, то cookie хранится в течение одного сеанса, до закрытия броузера.
• domain=DOMAIN_NAME - домен, для которого значение cookie действительно. Например, "domain=cit-forum.com". Если этот атрибут опущен, то по умолчанию используется доменное имя сервера, на котором было задано значение cookie.
• path=PATH - атрибут устанавливает подмножество документов, для которых действительно значение cookie. Для того, чтобы cookie отсылались при каждом запросе к серверу, необходимо указать корневой каталог сервера, например, "path=/". Если этот атрибут не указан, то значение cookie распространяется только на документы в той же директории, что и документ, в котором было установлено значение cookie.
• secure - если стоит этот маркер, то информация cookie пересылается только через HTTPS (HTTP с использованием SSL - Secure Socket Level), в защищенном режиме. Если этот маркер не указан, то информация пересылается обычным способом.

А вот примеров кода реально работающего фильтра практически нет. Восполняю этот пробел, возможно кому-нибудь пригодится.

Варианты кода для создания фильтра

Примеры разработаны для решения задачи:
Есть строка текста неопределенной длины. Надо эту строку сократить до определенного администратором числа символов.

Вариант 1. Самый простой

1) В модуле, где происходит создание объекта шаблона, создать подпрограмму-фильтр.

Например:

$MAX_LENGTH = 30;

sub filter {
	my $text = shift;

	if (length($text) > $MAX_LENGTH) {
		...
		# обработка переменной $text регулярными выражениями,
		# формирование ее нового значения
		...
	}
	return $text;
}

Фильтр, в данном случае, выполняет следующие действия: принимает данные для обработки, проводит обработку, возвращает измененные данные. В общем, это самая обыкновенная функция.

Кстати, можно разместить фильтр в другом модуле, а потом его просто подключить с помощью use.

2) В опции, которые задаются при создании объекта TemplateToolkit, добавляем параметр FILTERS.

...
	my $template_options = {
		...
		INCLUDE_PATH 	=> $templ_path,
		FILTERS => {
			'new_filter'  => \&filter,
		},
		...
	};

	my $template = Template->new($template_options) || do {
		$ERROR = "Can't create Template object: ".$Template::ERROR; 
		return undef;
	};
...

3) Фильтр создан и его можно использовать в шаблонах Template Toolkit, как любой другой фильтр:

[%- 'очень_длинная_фраза_которую_надо_укоротить' | new_filter -%]

Вариант 2

Создаем фильтр в виде подключаемого в шаблонах плагина.

1) Создаем плагин.

package Template_Plugin::MyNewFilter;

use Template::Plugin::Filter;

use base qw( Template::Plugin::Filter );

use vars qw(
	$FIRST_PART_LENGTH
	$LAST_PART_LENGTH
	$MAX_LENGTH
);

$FIRST_PART_LENGTH = 15;
$LAST_PART_LENGTH = 7;
$MAX_LENGTH = 30;

sub filter {
	my ($self, $text) = @_;

	if (length($text) > $MAX_LENGTH) {
		$text =~ /^(.{$FIRST_PART_LENGTH}).+(.{$LAST_PART_LENGTH})$/i;
		$text = $1.'...'.$2;
	}
	return $text;
}

1;

2) Плагин-фильтр должен располагаться пространстве имен, которое задается опциями, при создании объектов Template Toolkit.

...
	my $template_options = {
		...
		PLUGIN_BASE 	=> $TTPluginBase,
		...
	};
	my $template = Template->new($template_options) || 
		do {$ERROR = "Can't create Template object: 
		".$Template::ERROR; return undef;};
...

3) Используем получившийся плагин в шаблонах Template Toolkit.

[%- USE MyNewFilter -%]

[% FILTER $MyNewFilter %]очень_длинное_название_продукта_
которое_не_помещается_в_одной_строке[% END %]

Вариант 3. Самый правильный

Не знаю, как Вам, но мне не нравится указывать в шаблонах фильтр, с помощью знака доллара: FILTER $MyNewFilter . Если уж добавлять фильтр, как плагин, то и использовать, как обычный стандартный фильтр: FILTER MyNewFilter.

Поэтому, продолжаем поиски. И находим третий вариант создания фильтра.

package Template_Plugin::MyNewFilter;

use strict;
use Template::Plugin::Filter;
use base qw( Template::Plugin::Filter );

use vars qw(
	$FIRST_PART_LENGTH
	$LAST_PART_LENGTH
	$MAX_LENGTH
);

$FIRST_PART_LENGTH = 15;
$LAST_PART_LENGTH = 5;
$MAX_LENGTH = 30;

sub new {
	my ($class, $context, @params) = @_;

	my $self = {
		_CONTEXT => $context,
		_DYNAMIC => 1,
	};
       	bless $self, $class;
	$self->install_filter('MyNewFilter');

	return $self;
}

sub filter {
	my ($self, $text) = @_;

	if (length($text) > $MAX_LENGTH) {
		$text =~ /^(.{$FIRST_PART_LENGTH}).+(.{$LAST_PART_LENGTH})$/i;
		$text = $1.'...'.$2;
	}

	return $text;
}

1;

Стоит отметить, что метод install_filter предлагают использовать многие руководства по Template::Plugin::Filter, однако ни одно из них даже словом не упоминает, что необходимо создавать метод new, а так же - как его создавать. А без new стабильно работать будет только 500-ая ошибка сервера.

2) Не забываем, что плагин-фильтр должен быть размещен в определенном опцией PLUGIN_BASE пространстве имен.

3) Вот оно счастье - красивое использование фильтра:

[%- USE MyNewFilter -%]
[%- 'это-название-ни-в-какие-рамки-не-лезет' FILTER MyNewFilter -%]
или
[%- 'это-название-ни-в-какие-рамки-не-лезет' | MyNewFilter -%]

Полезные ссылки

Разнообразные теоретические аспекты создания фильтров можно узнать по приведенным ниже адресам:

http://www.template-toolkit.ru/Modules/Template/Plugin/Filter.html
http://www.template-toolkit.ru/Modules/Template/Plugin.html
http://search.cpan.org/~abw/Template-Toolkit-2.22/lib/Template/Plugin/Filter.pm
Книга: Perl Template Toolkit - O'Reilly - By Darren Chamberlain, David Cross, Andy Wardley